【小工具】影刀版本启动选择器

感谢@鹿秋夏 的idea和脚本，用更优雅的方式实现了启动不同影刀版本的方法。

脚本如下：

@echo off
setlocal enabledelayedexpansion
color f0
FOR /F "tokens=2*" %%a in ('REG QUERY "HKEY_CURRENT_USER\Software\ShadowBot x64" /v InstallPath 2^>nul') do set ProgramPath=%%b
if "%ProgramPath%"=="" (
    FOR /F "tokens=2*" %%a in ('REG QUERY "HKEY_CURRENT_USER\Software\ShadowBot x86" /v InstallPath 2^>nul') do set ProgramPath=%%b
)

if "%ProgramPath%"=="" (
    echo 未能找到影刀安装目录。
    pause
    exit
)

set count=0
for /f "tokens=*" %%d in ('dir /ad /b "%ProgramPath%" ^| findstr /b "shadowbot-" ^| sort /r') do (
    set /a count+=1
    set "folder!count!=%%d"
)

for /l %%i in (1,1,%count%) do (
    if %%i LSS 10 (set "num=0%%i") else (set "num=%%i")
    set "name=!folder%%i!"
    set "name=!name:shadowbot-=影刀-!"
    echo !num!: !name!
)

echo ------------------------------------------------------------------
:input
<nul set /p "=请输入对应版本的序号哟，未输入默认启动最新版本影刀:"
set /p choice=
if "%choice%"=="" (
    set choice=1
    goto start
)
if %choice% LSS 1 goto error
if %choice% GTR %count% goto error
goto start

:error
set choice=
echo 输入不正确，请重新输入哟.
goto input

:start
start "" "%ProgramPath%\!folder%choice%!\ShadowBot.Shell.exe"
endlocal

经过Cursor的简单处理，生成了下面这个带有UI的启动器，需要的小伙伴自行下载哈！

下载链接：https://wwst.lanzout.com/iOFx52i6lqcb